20.2.3.2 TReader对象的实现
Filer对象的作用主要是Delphi用来在DFM文件中读写各种类型的数据（包括部件对象）。这些数据的一个本质特征是变长，而且Filer对象将读写数据操作抽象化，包装成对象提供了大量的读写方法，方便了程序的调用。因此在应用程序中可以广泛使Filer对象，充分利用Delphi的面向对象技术。而且Filer对象与Stream对象捆绑在一起，一方面可以在各种存储媒介中存取任意格式的数据；另一方面，由于充分利用面向对象的动态联编，各种读写方法的使用方法是一致的，因此，方法调用很简单。下面我们着重介绍Reader 对象中与读写数据操作有关的属性和方法的实现。
1. TReader属性的实现
在TReader对象的属性实现中我们重点介绍Position的实现。
Position属性的定义了使用了读写控制，它们分别是GetPosition和SetPosition方法。
TReader = class(TFiler)
private
…
function GetPosition: Longint;
procedure SetPosition(Value: Longint);
public
…
property Position: Longint read GetPosition write
SetPosition;
end;
Postition的读写控制方法如下：
function TReader.GetPosition: Longint;
begin
Result := FStream.Position + FBufPos;
end;
procedure TReader.SetPosition(Value: Longint);
begin
FStream.Position := Value;
FBufPos := 0;
FBufEnd := 0;
end;
在TReader的父对象TFiler对象中介绍过FBufPos和FBufEnd变量。Filer对象内部分配了一个BufSize大小的缓冲区FBufPos就是指在缓冲区中的相对位置，FBufEnd是指在缓冲区中数据结束处的位置(缓冲区中的数据不一定会充满整个缓冲区)。
在GetPosition方法中可以看到Reader对象的Position值和Stream对象的Position值是不同的。Reader对象多了一个FButPos的编移量。
2. Defineproperty和DefineBinaryproperty方法的实现
这两个方法是虚方法，在TFiler中是抽象方法，在TReader和TWriter对象中才有具体的实现。
它们在TReader中的实现如下：
procedure TReader.DefineProperty(const Name: string;
ReadData: TReaderProc;
WriteData: TWriterProc; HasData: Boolean);
begin
if CompareText(Name, FPropName) = 0 then
begin
ReadData(Self);
FPropName := '';
end;
end;
procedure TReader.DefineBinaryProperty(const Name: string;
ReadData, WriteData: TStreamProc; HasData: Boolean);
var
Stream: TMemoryStream;
Count: Longint;
begin
if CompareText(Name, FPropName) = 0 then
begin
if ReadValue <> vaBinary then
begin
Dec(FBufPos);
SkipValue;
FCanHandleExcepts := True;
PropValueError;
end;
Stream := TMemoryStream.Create;
try
Read(Count, SizeOf(Count));
Stream.SetSize(Count);
Read(Stream.Memory^, Count);
FCanHandleExcepts := True;
ReadData(Stream);
finally
Stream.Free;
end;
FPropName := '';
end;
end;
在两个方法都将Name参数值与当前的属性名比较，如果相同则进行读操作。在DefineBinaryproperty中，创建了一个内存流。先将数据读到内存流中然后调用ReadData读取数据。
3. FlushBuffer的实现
FlushBuffer方法用于清除Reader对象的内部缓冲区中的内容，保持Reader对象和流在位置（Position）上的同步，其实现如下：
procedure TReader.FlushBuffer;
begin
FStream.Position := FStream.Position - (FBufEnd - FBufPos);
FBufPos := 0;
FBufEnd := 0;
end;
4. ReadListBegin、ReadListEnd和EndOfList方法
这三个方法都是用于从Reader对象的流中读取一连串的项目，并且这些项目都由WriteListBegin写入的标志标定开始和WriteListEnd写入标志，标定结束，在读循环中用EndOfList进行判断。它们是在Reader对象读取流中数据时经常用于的。它们的实现如下：
procedure TReader.ReadListBegin;
begin
CheckValue(vaList);
end;
procedure TReader.ReadListEnd;
begin
CheckValue(vaNull);
end;
function TReader.EndOfList: Boolean;
begin
Result := ReadValue = vaNull;
Dec(FBufPos);
end;
项目表开始标志是VaList，项目表结束标志是VaNull，VaList和VaNull都是枚举类型TValueType定义的常量。
它们实现中调用的CheckValue是TReader的私有方法，其实现如下：
procedure TReader.CheckValue(Value: TValueType);
begin
if ReadValue <> Value then
begin
Dec(FBufPos);
SkipValue;
PropValueError;
end;
end;
[1] [2] [3] [4] 下一页 |
